feat(conan-flake): add support to Conan C/C++ Package Manager config through conan-flake module

docs/src/individual-docs/languages/cplusplus.md

@@ -1,4 +1,221 @@
+## Getting Started
 
+The easiest way to get started with C++ is to simply enable it:
+
+```nix
+languages.cplusplus = {
+  enable = true;
+};
+```
+
+This will automatically:
+
+- Use `clang` as the default C++ package
+- Install it along with CMake and other tools
+
+Alternatively, you can manually specify packages:
+
+```nix
+languages.cplusplus = {
+  enable = true;
+  package = pkgs.stdenv.cc;
+};
+```
+
+## Setting up the [Conan](https://conan.io/) package manager
+
+Add conan-flake to your inputs:
+
+```shell-session
+$ devenv inputs add conan-flake git+https://codeberg.org/tarcisio/conan-flake
+```
+
+The conan-flake module bridges the gap between Nix and Conan, supporting a declarative configuration style. For instance, for a user profile configuration like the following:
+
+```ini
+[settings]
+build_type=Debug
+compiler.cppstd=14
+
+[platform_tool_requires]
+cmake/X.Y.Z
+```
+
+There correspond the following conan-flake options:
+
+```nix
+{
+  buildType = "Debug";
+  compilerCppStd = "14";
+
+  profiles.platformToolRequires = {
+    cmake = pkgs.cmake.version;
+  };
+
+  devShell = {
+    # Programs you want to make available in the shell:
+    tools = {
+      inherit (pkgs) cmake;
+    };
+  };
+}
+```
+
+You can check [the list of available options](/reference/options.md#languagescplusplusconanenable). The [`languages.cplusplus.conan.config`](/reference/options.md#languagescplusplusconanconfig) option, however, maps the whole of the options available in the [conan-flake](https://flake.parts/options/conan-flake.html) module — check the [official module documentation](https://flake.parts/options/conan-flake.html#options) and see the examples in [conan-flake's README file](https://codeberg.org/tarcisio/conan-flake/src/branch/main/README.md) to help you setting up.
+
+Config the `devenv.nix` file accordingly. For example:
+
+```nix
+languages.cplusplus = {
+  enable = true;
+  conan = {
+    enable = true;
+    install.enable = true;
+    config = {
+      buildType = "Debug";
+      compilerCppStd = "14";
+    };
+  };
+};
+```
+
+By default, when Conan is enabled:
+
+- The default C++ package is set to `config.stdenv.cc`
+- Conan is configured to use the same CMake available in the developmemnt shell; it's not necessary to set the `languages.cplusplus.conan.config.profiles.platformToolRequires.cmake` and `languages.cplusplus.conan.config.devShell.tools` options explicitly
+
+### In Action:
+
+```shell-session
+$ devenv shell
+Building shell ...
+Entering shell ...
+
+conan profile show # This would show the configured profile.
+```
+
+## Additional Examples
+
+### LLVM-based C++ Toolchain
+
+If you would like to integrate with the LLVM compiler infrastructure:
+
+```nix
+{ pkgs, ... }:
+
+{
+  languages.cplusplus = {
+    enable = true;
+    conan = {
+      enable = true;
+      install.enable = true;
+      config = {
+        stdenv = pkgs.overrideCC
+          (
+            pkgs.llvmPackages.libcxxStdenv.override {
+              targetPlatform.useLLVM = true;
+            }
+          )
+          pkgs.llvmPackages.clangUseLLVM;
+        # By default: compiler.libcxx=libstdc++11, so undo it:
+        compilerLibCxx = null;
+      };
+    };
+  };
+}
+```
+
+Or even:
+
+```nix
+{ pkgs, ... }:
+
+{
+  stdenv = pkgs.overrideCC
+    (
+      pkgs.llvmPackages.libcxxStdenv.override {
+        targetPlatform.useLLVM = true;
+      }
+    )
+    pkgs.llvmPackages.clangUseLLVM;
+
+  languages.cplusplus = {
+    enable = true;
+    conan = {
+      enable = true;
+      install.enable = true;
+      config = {
+        # By default: compiler.libcxx=libstdc++11, so undo it:
+        compilerLibCxx = null;
+      };
+    };
+  };
+}
+```
+
+In this second use case:
+
+- By default, conan-flake is configured using the same stdenv as devenv's (that is, `config.stdenv`)
+
+### In Action:
+
+```shell-session
+$ devenv shell
+Building shell ...
+Entering shell ...
+
+conan profile show # This would show the configured profile.
+conan create . --build=missing # This would create and test the current package.
+```
+
+### A local-recipe-index remote
+
+With [local-recipe-index](https://docs.conan.io/2/tutorial/conan_repositories/setup_local_recipes_index.html) remotes it's possible to declare dependencies from a simplified local index structure:
+
+```nix
+{
+  languages.cplusplus = {
+    enable = true;
+
+    conan = {
+      enable = true;
+      install.enable = true;
+
+      config = {
+        buildType = "Release";
+        compilerCppStd = "17";
+
+        remotes.local = {
+          url = "./repo";
+          local = true;
+          allowedPackages = [
+            "hello-world/0.0.1.cci.20260428"
+          ];
+        };
+
+        offline = true;
+      };
+    };
+  };
+}
+```
+
+The options in the `languages.cplusplus.conan.config` namespace:
+
+- `remotes.local.url`: is taken as a relative path to the root of the configuration
+- `offline`: enable only local remotes (that is, only of local-recipe-index type)
+
+### In Action:
+
+```shell-session
+$ devenv shell
+Building shell ...
+Entering shell ...
+
+conan profile show # This would show the configured profile.
+conan remote list # This would list the configured remotes.
+conan create . --build=missing # This would create and test the current package.
+```
 
 [comment]: # (Please add your documentation on top of this line)