nix-config/flake.nix at master · yunfachi/nix-config · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
{
  description = "Modular configuration of NixOS and Home Manager with Denix";

  outputs =
    { denix, nixpkgs, ... }@inputs:
    let
      mkConfigurations =
        moduleSystem:
        denix.lib.configurations rec {
          inherit moduleSystem;
          homeManagerUser = "yunfachi";

          paths = [
            ./hosts
            ./modules
            ./rices
          ];

          extensions = with denix.lib.extensions; [
            #rices
            args
            (base.withConfig {
              args.enable = true;

              hosts.features = {
                # cli: not must-have (ssh, git, gpg, fail2ban, dnscrypt) utilities like eza, bat, nh, etc.
                # gui: gui applications and modules that are needed only for gui applications (gnome-keyring, wakatime)
                features = [
                  "cli"
                  "gui"
                  "gaming"
                  "hacking"
                  "powersave"
                  "wireless"
                ];
                defaultByHostType = {
                  desktop = [
                    "cli"
                    "gui"
                    "gaming"
                    "hacking"
                  ];
                  server = [ ];
                };
              };
            })
          ];

          specialArgs = { inherit inputs moduleSystem; };
        };
    in
    {
      nixosConfigurations = mkConfigurations "nixos";
      homeConfigurations = mkConfigurations "home";

      devShells.x86_64-linux = {
        hacking = nixpkgs.legacyPackages.x86_64-linux.mkShell {
          name = "hacking";
          packages = with nixpkgs.legacyPackages.x86_64-linux; [
            # Recon
            findomain
            assetfinder
            nmap
            python313Packages.dirsearch
            # Reverse
            binwalk
            foremost
          ];
        };
      };
    };

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/master";
    home-manager = {
      url = "github:nix-community/home-manager/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    denix = {
      url = "github:yunfachi/denix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.home-manager.follows = "home-manager";
    };

    nixowos = {
      url = "github:yunfachi/NixOwOS";
      inputs.denix.follows = "denix";
    };
    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    impermanence.url = "github:nix-community/impermanence";
    nypkgs = {
      url = "github:yunfachi/nypkgs";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    sops = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    spicetify = {
      url = "github:Gerg-L/spicetify-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    anime-launcher = {
      url = "github:ezKEa/aagl-gtk-on-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    vscode-extensions = {
      url = "github:nix-community/nix-vscode-extensions";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    quickshell = {
      url = "git+https://git.outfoxxed.me/quickshell/quickshell";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    burpsuitepro = {
      url = "github:xiv3r/Burpsuite-Professional";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-config-wallpapers.url = "github:yunfachi/nix-config-wallpapers";
    wallpaper-manager = {
      url = "github:yunfachi/wallpaper-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
}