singularity-files/meson.build at main · singularityos-lab/singularity-files · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
project('singularity-files', ['vala', 'c'],
  version: '0.1.0',
  meson_version: '>= 0.59.0',
)

i18n = import('i18n')
add_project_arguments('-DGETTEXT_PACKAGE="singularity-files"', language: 'c')
subdir('po')

gnome = import('gnome')

# Dependencies
gtk_dep = dependency('gtk4')
gee_dep = dependency('gee-0.8')

# libsingularity dependency
if meson.is_subproject()
  libsingularity_subproj = subproject('libsingularity')
  libsingularity_dep = libsingularity_subproj.get_variable('libsingularity_dep')
else
  libsingularity_dep = dependency('singularity-1.0')
endif

# Compile .vetro to .ui in the ui/ subdirectory
subdir('ui')

# Resources
resources = gnome.compile_resources(
  'singularity-files-resources',
  'resources/dev.sinty.files.gresource.xml',
  source_dir: [meson.current_source_dir(), meson.current_build_dir()],
  dependencies: [main_ui, picker_ui]
)

sources = files(
  'src/main.vala',
  'src/window.vala',
  'src/app.vala',
  'src/connect_server_dialog.vala',
  'src/portal_service.vala',
  'src/file_ops_manager.vala',
  'src/files_plugin_manager.vala',
)

executable('singularity-files',
  sources: sources + [resources],
  dependencies: [
    gtk_dep,
    gee_dep,
    libsingularity_dep,
    dependency('libpeas-2'),
    dependency('json-glib-1.0'),
  ],
  install: true
)

# Data files
install_data('data/dev.sinty.files.desktop',
  install_dir: get_option('datadir') / 'applications'
)

install_data('data/dev.sinty.files.gschema.xml',
  install_dir: get_option('datadir') / 'glib-2.0' / 'schemas'
)

install_data('data/dev.sinty.files.json',
  install_dir: get_option('datadir') / 'singularity' / 'app-settings'
)

install_data('data/icons/dev.sinty.files.svg',
  install_dir: get_option('datadir') / 'icons' / 'hicolor' / 'scalable' / 'apps'
)

install_data('data/icons/ush-penguin.svg',
  install_dir: get_option('datadir') / 'icons' / 'hicolor' / 'scalable' / 'apps'
)

install_data('data/icons/ush-penguin-symbolic.svg',
  install_dir: get_option('datadir') / 'icons' / 'hicolor' / 'scalable' / 'apps'
)