vpv/flake.nix at master · kidanger/vpv · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
{
  description = "Image viewer for image processing experts";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        pkgs = nixpkgs.legacyPackages.${system};
        rustPlatform = pkgs.rustPlatform;
      in {
        packages = rec {
          vpv = pkgs.stdenv.mkDerivation rec {
            pname = "vpv";
            version = "0.9.0";
            src = ./.;

            cargoRoot = "src/fuzzy-finder";
            cargoDeps = rustPlatform.importCargoLock {
              lockFile = ./src/fuzzy-finder/Cargo.lock;
            };

            cmakeFlags = [
              "-DUSE_GDAL=ON"
              "-DUSE_OCTAVE=ON"
              "-DVPV_VERSION=${version}"
              "-DBUILD_TESTING=ON"
            ];

            nativeBuildInputs = with pkgs; [
              cmake
              pkg-config
              rustPlatform.cargoSetupHook
              cargo
            ];

            buildInputs = with pkgs;
              [
                libpng
                libtiff
                libjpeg
                SDL2
                gdal

                octave
                pkgs.octavePackages.image
              ]
              ++ lib.optionals stdenv.hostPlatform.isLinux [
                libGL
                xorg.libX11
              ];

            doCheck = true;
          };

          default = vpv;
        };
      }
    );
}