dev-python/pkg-resources: import from ::gentoo

Signed-off-by: Mathieu Tortuyaux <mtortuyaux@microsoft.com>

Author: tormath1

.github/workflows/portage-stable-packages-list

@@ -354,6 +354,7 @@ dev-python/packaging
 dev-python/pathspec
 dev-python/pefile
 dev-python/pip
+dev-python/pkg-resources
 dev-python/platformdirs
 dev-python/pluggy
 dev-python/ply

sdk_container/src/third_party/portage-stable/dev-python/pkg-resources/Manifest

@@ -0,0 +1 @@
+DIST setuptools-81.0.0.tar.gz 1198299 BLAKE2B a92fa15e03c99f6d7acbc0a24e6d3b4b31d514c031195b1dd0ae238611c44c3c979847c45437e5e4221fb8f750a7264fb55235ee7d4a8207ef19a67306d5360c SHA512 4dda2f0796d1a32d160e0786fc6ebb9908483e16edac6b0335df4779a0a8331f13b70fbf69986a27cc8f6ff10c1f696599059710fef99f36ff1e766f04220466

sdk_container/src/third_party/portage-stable/dev-python/pkg-resources/metadata.xml

@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches/>
+  <upstream>
+    <remote-id type="pypi">setuptools</remote-id>
+    <remote-id type="github">pypa/setuptools</remote-id>
+    <remote-id type="cpe">cpe:/a:python:setuptools</remote-id>
+  </upstream>
+</pkgmetadata>

sdk_container/src/third_party/portage-stable/dev-python/pkg-resources/pkg-resources-0.ebuild

@@ -0,0 +1,24 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit python-r1
+
+DESCRIPTION="pkg_resources compatibility shim"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	${PYTHON_DEPS}
+	<dev-python/setuptools-82[${PYTHON_USEDEP}]
+"

sdk_container/src/third_party/portage-stable/dev-python/pkg-resources/pkg-resources-81.0.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=no
+PYPI_PN=setuptools
+PYTHON_COMPAT=( python3_{12..15} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="pkg_resources package split from old setuptools"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	>=dev-python/jaraco-text-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-25.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-4.4.0[${PYTHON_USEDEP}]
+	!<dev-python/setuptools-82
+"
+BDEPEND="
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# requires setuptools wheel
+	pkg_resources/tests/test_integration_zope_interface.py
+)
+
+python_test() {
+	# needed only by setuptools
+	rm -f conftest.py || die
+	epytest -o filterwarnings= pkg_resources
+}
+
+python_install() {
+	# Let's install the module manually. We don't want a fake .dist-info
+	# for it.
+	python_domodule pkg_resources
+}