plugin-repositories.gradle

/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    https://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */

ext.configurePluginRepositories = { RepositoryHandler repositories ->
    if (System.getenv('GRAILS_INCLUDE_MAVEN_LOCAL')) {
        repositories.mavenLocal()
    }
    repositories.mavenCentral()
    repositories.gradlePluginPortal()
    repositories.maven {
        url = uri('https://repository.apache.org/content/groups/snapshots')
        content {
            includeGroup('org.apache.grails.gradle')
        }
        mavenContent {
            snapshotsOnly()
        }
    }
    repositories.maven {
        url = uri('https://central.sonatype.com/repository/maven-snapshots')
        content {
            includeGroupByRegex('cloud[.]wondrify[.].*')
            includeGroup('org.spockframework')
        }
        mavenContent {
            snapshotsOnly()
        }
    }
    repositories.maven {
        url = uri('https://repository.apache.org/content/groups/staging')
        content {
            includeModule('org.apache.grails.gradle', 'grails-publish')
            includeModuleByRegex('org[.]apache[.]groovy', 'groovy.*')
        }
        mavenContent {
            releasesOnly()
        }
    }
}