hibernate5-test-config.gradle

/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    https://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */

dependencies {
    // https://docs.gradle.org/8.3/userguide/upgrading_version_8.html#test_framework_implementation_dependencies
    add('testRuntimeOnly', 'org.junit.platform:junit-platform-launcher')
    add('testRuntimeOnly', 'net.bytebuddy:byte-buddy')
    add('testRuntimeOnly', 'org.objenesis:objenesis')
}

tasks.withType(GroovyCompile).configureEach {
    options.forkOptions.jvmArgs += ['-Dspock.iKnowWhatImDoing.disableGroovyVersionCheck=true']
}

tasks.withType(Test).configureEach {
    // Honor DO_NOT_CACHE_TESTS=1 so developers can repeatedly invoke the same test command
    // without --rerun-tasks (and without recompiling everything else).
    outputs.cacheIf { !doNotCacheTests }
    outputs.upToDateWhen { !doNotCacheTests }

    onlyIf {
        ![
                'onlyFunctionalTests',
                'onlyHibernate7Tests',
                'skipHibernate5Tests',
                'onlyMongodbTests',
                'onlyRedisTests',
                'onlySpringSecurityTests',
                'onlyCoreTests',
                'skipTests'
        ].find {
            project.hasProperty(it)
        }
    }

    useJUnitPlatform()
    // Lets TCK specs gate features on the running suite. Spock evaluates @IgnoreIf/@Requires
    // preconditions before setupSpec() runs, so this must be set at the task level - a
    // TCK-manager System.setProperty would come too late.
    systemProperty('hibernate5.gorm.suite', 'true')
    reports.html.required = !isCiBuild
    reports.junitXml.required = !isCiBuild
    testLogging {
        events('passed', 'skipped', 'failed')
        showExceptions = true
        exceptionFormat = 'full'
        showCauses = true
        showStackTraces = true

        // set options for log level DEBUG and INFO
        debug {
            events('started', 'passed', 'skipped', 'failed', 'standardOut', 'standardError')
            exceptionFormat = 'full'
        }
        info.events = debug.events
        info.exceptionFormat = debug.exceptionFormat
    }
    afterTest { desc, result ->
        logger.quiet(' -- Executed test {} [{}] with result: {}', desc.name, desc.className, result.resultType)
    }
    afterSuite { desc, result ->
        if (!desc.parent) { // will match the outermost suite
            def output = "Results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)"
            def startItem = '|  ', endItem = '  |'
            def repeatLength = startItem.length() + output.length() + endItem.length()
            def dashes = '-' * repeatLength
            logger.quiet('\n{}\n{}{}{}\n{}', dashes, startItem, output, endItem, dashes)
        }
    }
}