NixOS support

[rstacruz]

Great project, love the ideas behind Limux!

At the moment (0.1.14), the Limux builds don't work with nixos, not even the AppImages (appimage-run).

› ./Limux-0.1.14-x86_64.AppImage
Limux-0.1.14-x86_64.AppImage installed in /home/rsc/.cache/appimage-run/7b9d02640bf176936f1350f0a9bc0ebd7100f9b81b15ffff1f4cf62dc2fea0ea
/home/rsc/.cache/appimage-run/7b9d02640bf176936f1350f0a9bc0ebd7100f9b81b15ffff1f4cf62dc2fea0ea/usr/bin/limux: error while loading shared libraries: libgtk-4.so.1: cannot open shared object file: No such file or directory

This makes sense given "Limux still uses the host GTK4, libadwaita, and WebKitGTK runtime libraries", but it would be good to have an option available for NixOS somehow.

[whazor]

Package that works for me:

{
  lib,
  stdenv,
  fetchurl,
  autoPatchelfHook,
  makeWrapper,
  wrapGAppsHook4,
  gtk4,
  libadwaita,
  webkitgtk_6_0,
  glib,
  pango,
  fontconfig,
  gcc,
}:

stdenv.mkDerivation rec {
  pname = "limux";
  version = "0.1.19";

  src = fetchurl {
    url = "https://github.com/am-will/limux/releases/download/v${version}/limux-${version}-linux-x86_64.tar.gz";
    hash = "sha256-94/s5Iugdf3vbiwwVviGhVe5tSBnDi4Cbsib3yzeNNg=";
  };

  nativeBuildInputs = [
    autoPatchelfHook
    makeWrapper
    wrapGAppsHook4
  ];

  buildInputs = [
    fontconfig
    gcc.cc.lib
    glib
    gtk4
    libadwaita
    pango
    webkitgtk_6_0
  ];

  dontBuild = true;

  installPhase = ''
    runHook preInstall

    install -Dm755 limux "$out/bin/limux"
    install -Dm755 libexec/limux/limux-host "$out/libexec/limux/limux-host"
    install -Dm755 lib/libghostty.so "$out/lib/libghostty.so"
    cp -r share "$out/share"

    runHook postInstall
  '';

  preFixup = ''
    gappsWrapperArgs+=(
      --prefix LD_LIBRARY_PATH : "$out/lib"
      --prefix XDG_DATA_DIRS : "$out/share"
      --prefix TERMINFO_DIRS : "$out/share/limux/terminfo"
    )
  '';

  meta = {
    description = "GPU-accelerated terminal workspace manager for Linux";
    homepage = "https://github.com/am-will/limux";
    license = lib.licenses.mit;
    mainProgram = "limux";
    platforms = [ "x86_64-linux" ];
    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
  };
}

[bvolpato]

Valid packaging enhancement, not a fixed bug. Current AppImage still relies on host GTK4, libadwaita, and WebKitGTK, so NixOS needs a native derivation or wrapper. Community v0.1.19 derivation above is useful evidence, but repository has no maintained Nix package, flake, or CI.

A focused PR should package current source or release tarball, preserve public limux CLI plus private limux-host layout, install Ghostty resources and terminfo, wire WebKitGTK runtime, and add a reproducible flake/package check. Keeping open for that work.